Mike's AutoMagical AppleScript Solutions

10.4 Menu Extras scripting

Fri, 30 Dec 2005 03:24:15 GMT

In 10.4 we can land clicks on Menu Extras using System Events. It's a bit complicated by the fact that most menu extras don't have titles, and they can be placed in any order the user wishes.

The first time you run this script, it will start looking in your menu bar for the Bluetooth menu, and then use it to toggle Bluetooth on or off. On subsequent runs the script will have remembered where the Bluetooth menu is, and will just click it immediately. If the menu is later moved or removed, the script will go looking for it again.

click here to open this script in your editor

tell application "System Events" to tell the front menu bar of process "SystemUIServer"
	try
		click bt_menu
		tell the second menu item of the front menu of bt_menu to if title contains "Bluetooth" then
			click
		else
			error
		end if
	on error
		repeat with x in menu bar items
			click x
			try
				if the title of the first menu item of the front menu of x starts with "Bluetooth" then exit repeat
			end try
		end repeat
		set bt_menu to x
		try
			tell the second menu item of the front menu of bt_menu to if title contains "Bluetooth" then
				click
			else
				error
			end if
		on error
			click bt_menu
			display alert "Bluetooth Menu Extra not found."
		end try
	end try
end tell

Browse CoreTypes Icons

Wed, 28 Dec 2005 17:03:13 GMT

This is a script I wrote and posted to Apple Lists. It lets you see how various built-in system icons look when used in AppleScript dialog boxes. You can copy out the titles of your favorites, view them as a timed slideshow, pick one from a list, etc. When you quit the script it generates generic dialog code with the appropriate resource reference.

click here to open this script in your editor

-- contact_mike("Compose_Dialog_Icon_0.1.2") -- composes mail to the author and cancels script
set icon_delay to 1
set x to 0
set an_icon to ""
set icon_size to button returned of (display dialog "Which icon sizes would you like to view?" & return & "(10k and up is considered 'Large')" with title "Compose Dialog Icon 0.1.2" buttons {"Small", "Small + Large", "Large"} default button 2)
if icon_size is "Small" then
	tell application "Finder" to set core_icons to the name of every item of (((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle:Contents:Resources:") as alias) whose name extension is "icns" and size is less than 10000
else if icon_size is "Small + Large" then
	tell application "Finder" to set core_icons to the name of every item of (((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle:Contents:Resources:") as alias) whose name extension is "icns"
else if icon_size is "Large" then
	tell application "Finder" to set core_icons to the name of every item of (((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle:Contents:Resources:") as alias) whose name extension is "icns" and size is greater than 10000
end if
set delay_msg to "Enter a number of seconds to pause between icons:"
repeat
	display dialog delay_msg default answer icon_delay with title "Compose Dialog Icon 0.1.2" buttons {"Quit", "Choose Icon", "Start"} cancel button 1 default button 3
	tell result to set {icon_delay, nav_button} to {text returned, button returned}
	try
		set icon_delay to icon_delay as integer
		exit repeat
	on error
		set delay_msg to "Error: Number of seconds must be a positive integer."
	end try
end repeat
if nav_button is "Choose Icon" then
	repeat
		set an_icon to (choose from list core_icons default items an_icon) as string
		if an_icon is "false" then error number -128
		repeat with z from 1 to the length of core_icons
			if item z of core_icons is an_icon then exit repeat
		end repeat
		set x to z
		set an_icon to item x of core_icons
		set nav_button to button returned of (display dialog "Icon Title:" with title "Display Dialog" default answer an_icon with icon (path to resource an_icon in bundle ((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle") as alias) buttons {"Quit", "Choose Icon", "Start"})
		if nav_button is "Start" then
			set x to x - 1
			exit repeat
		else if nav_button is "Quit" then
			exit repeat
		end if
	end repeat
end if
if nav_button is "Start" then repeat
	set x to x + 1
	if x is greater than the length of core_icons then set x to 1
	set an_icon to item x of core_icons
	set nav_button to button returned of (display dialog "Icon Title:" with title "Display Dialog" default answer an_icon with icon (path to resource an_icon in bundle ((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle") as alias) giving up after icon_delay buttons {"Quit", "Previous", "Pause"} default button 3)
	if nav_button is not "" then repeat
		if nav_button is "Previous" then
			set x to x - 1
			if x is 0 then set x to the length of core_icons
			set nav_button to pause_view(item x of core_icons)
		else if nav_button is "Next" then
			set x to x + 1
			if x is greater than the length of core_icons then set x to 1
			set nav_button to pause_view(item x of core_icons)
		else if nav_button is "Pause" then
			set nav_button to pause_view(item x of core_icons)
		else if nav_button is "Resume" then
			set x to x - 1
			exit repeat
		else if nav_button is "Quit" then
			exit repeat
		end if
		
	end repeat
	if nav_button is "Quit" then exit repeat
end repeat
if nav_button is "Quit" then handle_quit(item x of core_icons)
on pause_view(an_icon)
	button returned of (display dialog "Icon Title:" with title "Display Dialog" default answer an_icon with icon (path to resource an_icon in bundle ((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle") as alias) buttons {"Resume", "Previous", "Next"} default button 1)
end pause_view
on handle_quit(an_icon)
	set icon_code to "display dialog \"\" with title \"\" default answer \"\" with icon (path to resource \"" & an_icon & "\" in bundle ((path to library folder from system domain as string) & \"CoreServices:CoreTypes.bundle\") as alias)"
	display dialog "Sample code for " & quoted form of an_icon with title "Quit" default answer icon_code buttons {"Quit", "Reveal Icon in Finder", "Copy Code to Clipboard"} cancel button 1 default button 3
	tell result to set {icon_code, copy_option} to {text returned, button returned}
	if copy_option is "Reveal Icon in Finder" then
		set icon_path to ((path to library folder from system domain as string) & "CoreServices:CoreTypes.bundle:Contents:Resources:" & an_icon) as alias
		tell application "Finder"
			activate
			set icon_window to make new Finder window
			tell icon_window
				set target to icon_path
				set current view to icon view
				set toolbar visible to false
			end tell
			tell icon view options of icon_window
				set arrangement to arranged by name
				set shows icon preview to true
				set icon size to 128
			end tell
			reveal icon_path
		end tell
	else if copy_option is "Copy Code to Clipboard" then
		set the clipboard to icon_code
	end if
end handle_quit
to contact_mike(script_revision)
	open location "mailto:mike.com@mac.com?subject=" & script_revision
	error number -128
end contact_mike

Fun with hijacking command parameters

Thu, 08 Dec 2005 19:13:54 GMT

So I discovered an exciting new behavior in AppleScript today. That is you can 'hijack' commands and make them do pretty much whatever you want, including the command that they're intended to do. I'm not sure what exactly this is useful for, but it's a lot of fun!

click here to open this script in your editor

beep 2

on beep x
	say "So, you want me to beep " & x & " times, eh?"
	delay 3
	continue beep x
end beep

on delay y
	repeat y times
		continue delay 1
		say "hmmm"
	end repeat
	say "ok"
end delay

Save all Safari Tabs as PDF

Mon, 28 Nov 2005 02:24:12 GMT

http://forums.macosxhints.com/showthread.php?p=250292
Are there any Applescripts that allow me to automate saving to PDF? (In particular saving all open tabs in the browser as PDF files).

http://www.macosxhints.com/article.php?story=20031116190809396

The original hint (at the top) is pretty much accurate, except that you hold down the option key not while clicking 'Add' but while clicking 'More Printers.' This distinction was made in a more recent comment (at the bottom) of that page.

click here to open this script in your editor

(*
This script cycles through Safari tabs, and
prints each page to a virtual PDF printer.

To set up a PDF printer in OS X, follow
the instructions on this page:

http://www.macosxhints.com/article.php?story=20031116190809396
*)

set printer_name to "PDFWriter"
set print_history to {}

if check_gui() is true then
	activate application "Safari"
	repeat
		tell application "Safari"
			set this_page to URL of document 1
			if this_page is not in print_history then
				copy this_page to the end of print_history
				print the front document with properties {target printer:printer_name} without print dialog
				tell application "System Events" to tell front menu bar of application process "Safari"
					click menu item "Select Next Tab" of front menu of menu bar item "Window"
				end tell
			else
				exit repeat
			end if
		end tell
	end repeat
end if


on check_gui()
	tell application "System Events"
		get system attribute "sysv"
		if result is greater than or equal to 4144 then -- Mac OS X 10.3.0
			if UI elements enabled then
				return true
			else
				beep
				display dialog "GUI Scripting is not enabled" & return & return & "Open System Preferences and check Enable Access for Assistive Devices in the Universal Access preference pane, then run this script again." with icon stop
				if button returned of result is "OK" then
					tell application "System Preferences"
						activate
						set current pane to pane "com.apple.preference.universalaccess"
					end tell
				end if
			end if
		else
			beep
			display dialog "This computer cannot run this script" & return & return & "The script uses GUI Scripting technology, which requires an upgrade to Mac OS X 10.3 Panther or newer." with icon caution buttons {"Quit"} default button "Quit"
		end if
		return false
	end tell
end check_gui

Internet Connect GUI Script for 802.1x

Mon, 28 Nov 2005 02:19:33 GMT

Is there a way to script a new 802.1x connection in internet connect?
http://discussions.apple.com/message.jspa?messageID=1209683

click here to open this script in your editor

-- Adjust these values to taste:
set my_description to "Foobar Conf"
set my_configuration to "Other"
set my_network_port to "AirPort"
set my_username to "foo"
set my_password to "bar"
set my_wireless_network to "foobar"
--
if check_gui() is false then error number -128
activate application "Internet Connect"
tell application "System Events"
	tell the front window of process "Internet Connect"
		click button "802.1X" of the first tool bar
		tell the 2nd pop up button
			click
			click menu item my_configuration of the front menu
		end tell
		tell the 1st pop up button
			click
			click menu item my_network_port of the front menu
		end tell
		copy my_username to the value of the 2nd text field
		copy my_wireless_network to the value of the first combo box
	end tell
	keystroke tab
	key code 123
	repeat with x from 1 to the length of my_password
		keystroke character x of my_password
	end repeat
	tell the front window of process "Internet Connect"
		click button "Summary" of the first tool bar
		tell the front sheet
			copy my_description to the value of the first text field
			click button "Save"
		end tell
	end tell
end tell
quit application "Internet Connect"
--
on check_gui()
	tell application "System Events"
		get system attribute "sysv"
		if result is greater than or equal to 4144 then -- Mac OS X 10.3.0
			if UI elements enabled then
				return true
			else
				beep
				display dialog "GUI Scripting is not enabled" & return & return & "Open System Preferences and check Enable Access for Assistive Devices in the Universal Access preference pane, then run this script again." with icon stop
				if button returned of result is "OK" then
					tell application "System Preferences"
						activate
						set current pane to pane "com.apple.preference.universalaccess"
					end tell
				end if
			end if
		else
			beep
			display dialog "This computer cannot run this script" & return & return & "The script uses GUI Scripting technology, which requires an upgrade to Mac OS X 10.3 Panther or newer." with icon caution buttons {"Quit"} default button "Quit"
		end if
		return false
	end tell
end check_gui

Sticky Note Mail Rule

Sun, 27 Nov 2005 19:39:17 GMT

"I want to be able to email notes to a certain email address and then, when I get home and check my mail, have each of those emails turned into a brand-new sticky note on my desktop."-nightbird
http://www.livejournal.com/community/applescript/20620.html?style=mine

click here to open this script in your editor

-- contact_mike("Sticky_Note_Mail_Rule_0.2.1") -- composes mail to the author and cancels script
using terms from application "Mail"
	on perform mail action with messages the_messages
		try
			set rule_folder to "Stickies"
			tell application "Mail"
				repeat with a_message in the_messages
					set a_note to ""
					repeat with x from 1 to 5
						set a_note to paragraph x of a_message's content as Unicode text
						if a_note is not "" then exit repeat
					end repeat
					set the clipboard to a_note
					activate application "Stickies"
					if check_gui() of me is false then error number -128
					tell application "System Events" to tell the front menu bar of process "Stickies"
						click menu item "New Note" of the front menu of menu bar item "File"
						tell the front menu of menu bar item "Edit"
							click menu item "Check Spelling as You Type" of the front menu of menu item "Spelling"
							click menu item "Paste"
						end tell
					end tell
					set the read status of a_message to true
					move a_message to the mailbox "Trash"
				end repeat
			end tell
		on error the error_message number the error_number
			tell me to activate
			set error_msg to "Error: " & the error_number & ". " & the error_message
			display dialog error_msg buttons {"Cancel", "Copy Error to Clipboard"} default button 2
			set the clipboard to error_msg
		end try
	end perform mail action with messages
end using terms from
on check_gui()
	tell application "System Events"
		get system attribute "sysv"
		if result is greater than or equal to 4144 then -- Mac OS X 10.3.0
			if UI elements enabled then
				return true
			else
				beep
				display dialog "GUI Scripting is not enabled" & return & return & "Open System Preferences and check Enable Access for Assistive Devices in the Universal Access preference pane, then run this script again." with icon stop
				if button returned of result is "OK" then
					tell application "System Preferences"
						activate
						set current pane to pane "com.apple.preference.universalaccess"
					end tell
				end if
			end if
		else
			beep
			display dialog "This computer cannot run this script" & return & return & "The script uses GUI Scripting technology, which requires an upgrade to Mac OS X 10.3 Panther or newer." with icon caution buttons {"Quit"} default button "Quit"
		end if
		return false
	end tell
end check_gui
to contact_mike(script_revision)
	open location "mailto:mike.com@mac.com?subject=" & script_revision
	error number -128
end contact_mike

Detect sound activity with AppleScript

Fri, 18 Nov 2005 19:02:00 GMT

Wake display with a sound, any sound.
"how can I use the integrated microphone for to wake the screen any time a nois is detected and keep it on until a no noise is detected for a certain amount od time?"

There may be a better way to do this, but the first thing that came to my mind was VOX voice-activated recording apps. The one I test here is the shareware Audiocorder 4.5 [USD$20] you can download a demo here:
http://www.versiontracker.com/dyn/moreinfo/macosx/10417

Edit: The following script is an applet because I was originally attempting to monitor audiocorder's gui for the trigger. It seems however that the GUI is unavailable during a screensaver/display sleep event. The script in its present form could be easily written as a folder action, which would cause less performance issues.
All I did was save the following code as a 'stay-open application' with Script Editor, and then left it running while Audiocorder was set to 'VOX' mode. The moment the VOX audio threshold was exceeded it created a new audio file, which the script detected immediately and woke the display.

Please note that this script assumes that you've enabled access for assistive devices on the universal access pane of system preferences, and that you've selected require password to wake this computer from sleep or screen saver on the security pane of system preferences.

click here to open this script in your editor

property old_count : integer
set the old_count to the new_count()

on idle
	if the new_count() is greater than the old_count then
		set the old_count to the new_count()
		tell application "System Events"
			key code 53
			delay 3
			key code 53
		end tell
	end if
	return 0.5
end idle

on new_count()
	tell application "Finder" to count (path to application "Audiocorder OSX")'s container's items
end new_count

Extract text from complex web sites

Fri, 18 Nov 2005 18:49:41 GMT

Re: Web text to word
"I want to copy all the text in my current safari web page and put it into ms word."

I thought this would be a simple thing to do, and it may be simple in Word 2004, but I only have Word v.X, and everything I tried was either failing entirely, failing half the time, or producing garbled results. The only clean way I found to accomplish this task on my machine was to pass the text through both TextEdit and 10.4 Tiger's 'textutil' before opening a temporary file in Word. This isn't a particularly concise script, nor is it terribly obvious, but it works, and the results are on par with what you'd get using Word's 'paste special' feature.

click here to open this script in your editor

"/tmp/my_doc.txt"
set my_file to POSIX file result
tell application "Safari"
	open location "http://news.google.com/"
	delay 5 -- wait for page to load, adjust as needed
	set my_text to the text of the front document
end tell
tell application "TextEdit"
	-- NOTE: this step only works correctly if you've set TextEdit
	-- preferences to use 'Plain Text' for the new document format.
	set my_doc to make new document with properties {text:my_text}
	close my_doc saving in my_file
end tell
do shell script "cd /tmp; textutil -convert rtf -font Times -fontsize 10 my_doc.txt"
"/tmp/my_doc.rtf"
set my_file to POSIX file result
tell application "Microsoft Word" to open my_file

Script iChat login accounts

Fri, 18 Nov 2005 18:43:16 GMT

Re: Switching iChat Accounts
On Nov 14, 2005, at 9:36 PM, Ed McNichol wrote:
I have 15 users who share three computers. Each COMPUTER has an iChat account. I want the user logged into the iChat account appropriate for that computer. Users preferences are shared from a network log on. I would like to script this to happen at log on.

On Nov 15, 2005, at 19:08:08, Dave Lyons wrote:
I don't know how to make this work, but I got a little bit further. The dictionary indicates that "log in" takes a reference to the account to be logged in

From what I can tell this is just a case of a misleading dictionary entry. The only object I can get iChat's 'log in' command to accept is a reference to the service (AIM, Bonjour, Jabber) that is to be logged into. Accounts themselves are defined in iChat preferences, and only one can be the 'default' account for each service. Here's a script I wrote that switches between the two AIM accounts that I've set up in iChat. Perhaps you can modify this so that it's useful for your situation.

click here to open this script in your editor

tell application "iChat" to quit
tell application "System Events"
	if "iChatAgent" is in name of every process then do shell script "killall iChatAgent"
	tell the property list file ((path to preferences as string) & "com.apple.iChat.AIM.plist")
		set aim_accounts to name of property list items of property list item "Accounts"
		set active_account to value of property list item "ActiveAccount"
		repeat with x in aim_accounts
			set y to the contents of x
			if y is not the active_account then
				copy y to the value of property list item "ActiveAccount"
			end if
		end repeat
	end tell
end tell
tell application "iChat" to log in service "AIM"

Whereas you could modify the script I just posted to select a particular AIM account to sign into, I just discovered that it's also possible to get iChat to log in to an arbitrary screen name specified by the script. My method is to overwrite the screen name of the first account in iChat prefs. This is problematic if you want to actually keep that account the way it was, but iChat otherwise handles the new name without a hitch, and even prompts for a new password to store in the keychain.

click here to open this script in your editor

sign on "foo"

to sign on an_account
	tell application "iChat" to quit
	tell application "System Events"
		if "iChatAgent" is in name of every process then do shell script "killall iChatAgent"
		tell the property list file ((path to preferences as string) & "com.apple.iChat.AIM.plist")
			tell the first property list item of property list item "Accounts"
				copy name to account_id
				copy an_account to the value of property list item "LoginAs"
			end tell
			copy account_id to the value of property list item "ActiveAccount"
		end tell
	end tell
	tell application "iChat" to log in service "AIM"
end sign

Droplet to compose a Mail message with attachments

Fri, 18 Nov 2005 18:18:11 GMT

Re: Automator question regarding email
"I have managed to make an Automator application where if I drag a document onto the action - it opens a new Mail message with that document as the attachment. The action also puts the specified person's email address in the Mail message's address box. What I would like to add - is that the NAME of the document which I drag onto the Automator Application, becomes the SUBJECT line of the new Mail message."

This may be out of line in an Automator forum, but I think you need an AppleScript to accomplish this. I wrote an AppleScript droplet for you that does what you want, and as an added bonus it will accept drag and drop multiple-item finder selections as well as single-item. If there is more than one item the script will add each file to the new mail message, and add each file name to the subject as well, separated by commas.

To use the script, click the following link to open it in Script Editor, then save it to your hard drive using the 'File Format: Application' option in Script Editor's save dialog. The three other save options should be left unchecked.

click here to open this script in your editor

on open my_files
	
	-- change the following variable to your recipient's adddress
	set an_address to "jdoe@apple.com"
	
	-- or, alternatively, remove the '--' from the next line to get a dialog
	-- set an_address to text returned of (display dialog "New E-mail Recipient:" default answer "")
	
	set my_subject to {}
	tell application "Finder" to repeat with x in my_files
		set my_subject to my_subject & (name of contents of x)
	end repeat
	set {TID, text item delimiters} to {text item delimiters, ", "}
	set {my_subject, text item delimiters} to {my_subject as Unicode text, TID}
	tell application "Mail"
		activate
		set my_message to make new outgoing message with properties {subject:my_subject}
		tell my_message
			set visible to true
			make new to recipient at end of to recipients with properties {address:an_address}
			repeat with x in my_files
				tell content to make new attachment with properties {file name:(contents of x)} at after the last paragraph
			end repeat
			-- remove the '--' from the next line to send the message automatically
			-- send
		end tell
	end tell
end open

Here is a significantly updated and enhanced version of this script. It adds in a preference system among other things:

click here to open this script in your editor

property an_address : "jdoe@apple.com"
property a_name : "Jane Doe"
property proj_name : "Generic Project"
property hide_ext : "NO"
property auto_send : "NO"
property add_label : "NO"
property a_label : " - Final"
property add_form : "NO"
property prompt_address : "NO"
property prompt_label : "NO"
property prompt_project : "NO"
property form_letter : "Hello *NAME*,

Attached are the files for \"*PROJ*.\"

Thank you,
My Name
"
(* the preceding are merely default values, they
do not need to be edited here, and will only
reset when the script is recompiled *)
on run
	repeat
		set {label_preview, form_preview} to {"NO - Add Label", "NO - Add Form Letter"}
		if add_label is "YES" then set label_preview to "YES - Add Label " & quoted form of a_label
		if add_form is "YES" then set form_preview to "YES - Add Form Letter:" & return & return & form_letter
		
		display dialog "Recipient: " & a_name & space & (quoted form of an_address) & return & "
" & hide_ext & " - Hide File Extensions
" & auto_send & " - Auto-Send
" & label_preview & return & form_preview & return & "
Always Prompt for: 
" & prompt_address & " - Recipient
" & prompt_label & " - Label
" & prompt_project & " - Project" with title "Script Preferences" buttons {"Edit Recipient", "Other Settings", "OK"} default button 3
		copy button returned of result to my_option
		if my_option is "Edit Recipient" then
			set an_address to text returned of (display dialog "Edit E-mail Recipient:" default answer an_address)
			display dialog "Edit Recipient's Name:" default answer a_name buttons {"Other Settings", "OK"}
			copy {text returned, button returned} of result to {a_name, my_option}
		end if
		if my_option is "Other Settings" then
			set hide_ext to button returned of (display dialog "Shall the script hide all file extensions?" with title "Hide File Extenstions" buttons {"YES", "NO"} default button def_int(hide_ext))
			set auto_send to button returned of (display dialog "Shall the script automatically send the message when it runs?" with title "Auto-Send" buttons {"YES", "NO"} default button def_int(auto_send))
			set add_label to button returned of (display dialog "Shall the script add a label to each file name?" with title "Add Labels" buttons {"YES", "NO"} default button def_int(add_label))
			if add_label is "YES" then set a_label to text returned of (display dialog "Edit Label:" default answer a_label buttons {"OK"} default button 1)
			set add_form to button returned of (display dialog "Shall the script add a form letter to each message?" with title "Add Form Letter" buttons {"YES", "NO"} default button def_int(add_form))
			if add_form is "YES" then set form_letter to text returned of (display dialog "Edit your form letter. The placeholders *NAME* and *PROJ* are automatically replaced with the appropriate values at run time." with title "Edit Form Letter" default answer form_letter buttons {"OK"} default button 1)
			set prompt_labels to {"Recipient Address", "File Label", "Project Name", ""}
			set my_prompt_settings to {prompt_address, prompt_label, prompt_project, ""}
			set my_prompts to {}
			repeat with x from 1 to the length of prompt_labels
				if item x of my_prompt_settings is "YES" then set end of my_prompts to item x of prompt_labels
			end repeat
			set my_prompts to (choose from list prompt_labels with prompt "Select items to confirm at run time." & return & return & "Use the command key to select multiple items" default items my_prompts with title "Prompt Options" with multiple selections allowed and empty selection allowed) as list
			set {prompt_address, prompt_label, prompt_project} to {"NO", "NO", "NO"}
			if "Recipient Address" is in my_prompts then set prompt_address to "YES"
			if "File Label" is in my_prompts then set prompt_label to "YES"
			if "Project Name" is in my_prompts then set prompt_project to "YES"
		end if
		if my_option is "OK" then exit repeat
	end repeat
end run
on def_int(bool)
	if bool is "YES" then return 1
	return 2
end def_int
on open my_files
	set {TID, text item delimiters} to {text item delimiters, ""}
	if prompt_address is "YES" then set an_address to text returned of (display dialog "Edit E-mail Recipient:" default answer an_address)
	if prompt_label is "YES" then
		set add_label to "YES"
		set a_label to text returned of (display dialog "Enter a new label, or leave blank for no label." with title "Edit Label" default answer a_label)
	end if
	if prompt_project is "YES" then set proj_name to text returned of (display dialog "Edit Project Name:" default answer proj_name)
	set my_subject to {}
	if hide_ext is "YES" then
		tell application "Finder" to repeat with x in my_files
			try
				set AppleScript's text item delimiters to ("." & (name extension of contents of x))
				set my_subject to my_subject & (first text item of (name of contents of x as Unicode text))
			end try
		end repeat
	else
		tell application "Finder" to repeat with x in my_files
			set my_subject to my_subject & (name of contents of x)
		end repeat
	end if
	set text item delimiters to ""
	if add_label is "YES" then
		repeat with x from 1 to the length of my_subject
			set item x of my_subject to (item x of my_subject & a_label as Unicode text)
		end repeat
	end if
	set text item delimiters to ", "
	set my_subject to my_subject as Unicode text
	set final_form to ""
	if add_form is "YES" then
		set text item delimiters to "*NAME*"
		set final_form to form_letter's text items
		set text item delimiters to a_name
		set final_form to final_form as Unicode text
		set text item delimiters to "*PROJ*"
		set final_form to final_form's text items
		set text item delimiters to proj_name
		set final_form to final_form as Unicode text
		set text item delimiters to ""
	end if
	tell application "Mail"
		activate
		set my_message to make new outgoing message with properties {subject:my_subject, content:final_form & return & return} -- add code:/ sender:"foo@bar.com", /:code to this record to send from a particular account.
		tell my_message
			set visible to true
			make new to recipient at end of to recipients with properties {address:an_address}
			repeat with x in my_files
				tell content to make new attachment with properties {file name:(contents of x)} at after the last paragraph
			end repeat
			if auto_send is "YES" then send
		end tell
	end tell
	set text item delimiters to TID
end open
(* written November 24, 2005 by Michael Henley
mike.com@mac.com *)

Assign unique filenames to screen captures

Thu, 17 Nov 2005 19:47:15 GMT

Re: How could I modify this script to make the name of each file unique?

There are many ways to do this. For one, if you define a 'property' instead of a 'global' then the script will remember any variable you like for just about eternity. Between runs, between boots, you name it. The only thing that would reset the property to its default setting is re-compiling the script itself.

But giving each file a unique name is more useful, and there are as many ways to do this as there are ways to slice and dice the results of AppleScript's 'current date' command.

Here is my suggestion, it outputs files that look like this:

screen 17-Nov-2005 1.10.30 AM.pdf
screen 17-Nov-2005 1.10.40 AM.pdf
screen 17-Nov-2005 1.10.50 AM.pdf
screen 17-Nov-2005 1.11.00 AM.pdf
screen 17-Nov-2005 1.11.10 AM.pdf

Note that I tweaked your script so that it takes screenshots precisely at each 10th second of each minute. This was just an aesthetic consideration for me, feel free to omit it.

click here to open this script in your editor

property x : 0
set x to 0

tell (current date)'s time to 10 - it mod 10
delay result

on idle
	do shell script "screencapture -x ~/snaps/" & ¬
		quoted form of ("screen " & get_time() & ".pdf")
	set x to x + 1
	if x = 5 then quit
	tell (current date)'s time to 10 - it mod 10
end idle

on get_time()
	set {TID, text item delimiters} to {text item delimiters, ""}
	tell (current date)
		set am to "AM"
		set d to "."
		set z to it's hours
		if z > 12 then
			set am to "PM"
			set z to z - 12
		end if
		set y to it's minutes as string
		if length of y is 1 then set y to "0" & y
		set timestring to z & d & y & d & it's seconds & space & am as string
		(it's day as integer) & "-" & characters 1 thru 3 of (it's month as string)
		set timestamp to result & "-" & it's year & space & timestring as string
	end tell
	set text item delimiters to TID
	return timestamp
end get_time

AppleScript calling LiveJournal

Sun, 11 Sep 2005 04:39:19 GMT

Here's a simple script I wrote that you can use to post directly to LiveJournal from AppleScript. This is only a small example of how you can interact with LiveJournal using AppleScript. For more information on their XML-RPC implementation and syntax, look here. Remember that AppleScript treats structs as {{|records|:within, |single|:parameters}}, and don't forget to |pipe| all your labels (which should match LJ's xml fields) to prevent scripting addition conflicts.

-- the name of your livejournal account
set my_name to "YOUR USERNAME"

-- the subject line for you entry:
set my_topic to "I'm Awesome!"

-- the body of your entry:
set my_post to "I posted this directly from AppleScript using LiveJournal's XML-RPC API. Kickass."

-- password dialog (sent in the clear, see LJ docs for safer methods)
copy {text returned of (display dialog "Enter password for " & quoted form of my_name with title ¬
	"LiveJournal Post Event" with icon stop default answer "" with hidden answer), "clear"} to ¬
	{my_pass, my_auth}

-- figure out the time and date of your post based on local system time
set post_time to time of (current date)
if post_time ≥ hours then
	copy {post_time div hours, post_time mod hours} to ¬
		{my_hour, minute_x}
	copy {minute_x div minutes, minute_x mod minutes} to ¬
		{my_minute, my_second}
else if post_time ≥ minutes then
	copy {0, post_time div minutes, post_time mod minutes} to ¬
		{my_hour, my_minute, my_second}
else
	copy {0, 0, post_time} to {my_hour, my_minute, my_second}
end if
current date
copy {year of result, month of result as integer, day of result} to {my_year, my_month, my_day}

-- the actual post event
tell application "http://www.livejournal.com/interface/xmlrpc" to call xmlrpc ¬
	{method name:"LJ.XMLRPC.postevent", parameters:¬
		{{username:my_name, auth_method:my_auth, |password|:my_pass, |event|:¬
			my_post, lineendings:"mac", subject:my_topic, security:"", allowmask:0, |year|:¬
			my_year, mon:my_month, |day|:¬
			my_day, hour:my_hour, min:my_minute}}}

-- open the entry in your default browser
open location (|url| of result)

x-posted

Upload ScreenCap 0.2

Mon, 18 Jul 2005 02:08:17 GMT

This script will take a screenshot at regular
intervals, resize it, and then upload it to a web
server.

(*
Upload ScreenCap
Written by Michael Henley (mike.com@mac.com)
version 0.2 (17Jul05)

This script will take a screenshot at regular 
intervals, resize it, and then upload it to a web 
server.

To use the script, simply copy this code to Script 
Editor (in your applications/AppleScript folder) 
and save it as an Application with the "stay open" 
option selected.

You should also edit the values set in the "on 
run" handler so that the script knows where to 
upload your file.
*)

global interval, capSize, capTitle, uploadLoc

on run
	set interval to 5 * 60 -- update frequency (5min x 60sec = 300sec)
	set capSize to 800 -- the max re-size value in pixels
	set capTitle to "screencap.jpg" -- the name of the image file
	set uploadLoc to "http://USER:PASS@idisk.mac.com/mike.com/Sites/" (* the URL to your server
	you can protect your user/pass by saving this script using
	the "Run Only" option (uneditable) or you can omit it and
	add "with authentication" where indicated in the script. *)
end run

on idle
	do shell script "screencapture " & quoted form of ("/" & capTitle)
	tell application "Finder" to set screenCap to ((startup disk as string) & capTitle)
	tell application "Image Events"
		set theImage to open file screenCap as alias
		scale theImage to size capSize
		save theImage as JPEG
		-- acceptable format names: BMP JPEG JPEG2 PICT PNG PSD QuickTime Image TIFF
		close theImage
	end tell
	tell application "URL Access Scripting" to upload screenCap to uploadLoc -- with authentication
	return interval
end idle

Safe Delete 0.2

Mon, 18 Jul 2005 02:04:48 GMT

This script can be used as a "safe" alternative
to the standard iTunes delete command. To use
it, simply select one or more tracks in your
iTunes library that you'd like to delete, and
then run the script. The script will attempt to
delete those files after checking to see if they
appear in any of your user playlists. If a
particular track appears in one or more
playlists, the script displays a dialog box that
asks if you're certain you want to delete that
particular track. The dialog box will tell you
the name of the track, and the name of each
playlist it appears in, excluding smart
playlists and party shuffle.

(*
Safe Delete version 0.2a

This script can be used as a "safe" alternative 
to the standard iTunes delete command.  To use 
it, simply select one or more tracks in your 
iTunes library that you'd like to delete, and 
then run the script.  The script will attempt to 
delete those files after checking to see if they 
appear in any of your user playlists. If a 
particular track appears in one or more 
playlists, the script displays a dialog box that 
asks if you're certain you want to delete that 
particular track.  The dialog box will tell you 
the name of the track, and the name of each 
playlist it appears in, excluding smart 
playlists and party shuffle.

The script is still being tested, therefore it 
is defaulted to a "test mode" that can't delete 
any files in your library.  If you want to make 
the script work normally, you must replace the 
line "set testMode to true" with "set testMode 
to false"

July 13, 2005
Written by Michael Henley (mike.com@mac.com)

File History:
13Jul05
- streamlined comparison routine to improve speed.
- now pre-loads all playlist data into a variable.
- now includes Purchased Music, if available.
- fixed a delete track bug
- fixed a bug where blank playlists could
  cause the script to malfunction.
*)
tell application "iTunes"
        set everyList to name of user playlists whose smart is false
        set selectedIDs to database ID of selection
        set selectedTitles to name of selection
        set everyListName to {}
        set everyListID to {}
        repeat with z from 2 to (count everyList) -- skip Party Shuffle
                set listName to item z of everyList as string
                set everyListName to everyListName & listName as list
                try
                        set everyListID to everyListID & {database ID of tracks of playlist listName} as list
                on error
                        set everyListID to everyListID & {"" as list} as list
                end try
        end repeat
        repeat with x from 1 to (count selectedIDs)
                set anID to item x of selectedIDs
                set trackCheck to (item x of selectedTitles as string)
                set checkFlag to false
                set listCheck to ""
                repeat with y from 1 to (count everyListID)
                        set anListID to item y of everyListID
                        if anListID contains anID then
                                set listName to item y of everyListName as string
                                set checkFlag to true
                                set listCheck to listCheck & return & listName
                        end if
                end repeat
                if checkFlag then
                        display dialog "The track \"" & trackCheck & "\"" & return & "is in the following playlists:" & return ¬
                                & listCheck & return & return & "Do you want to delete it anyway?" buttons {"yes", "no"} default button 2
                        if the button returned of the result is "yes" then my deleteTrack(trackCheck)
                else
                        my deleteTrack(trackCheck)
                end if
        end repeat
end tell
on deleteTrack(trackCheck)
        set testMode to true -- change this to false if you want the script to work normally.
        tell application "iTunes"
                if testMode then
                        display dialog "I did not delete the track \"" & trackCheck & "\"" & return & "because I am in test mode."
                else
                        set trackPath to location of track trackCheck of library playlist 1
                        delete track trackCheck of library playlist 1
                        tell application "Finder" to move trackPath to trash
                end if
        end tell
end deleteTrack

HyperSafari 1.0

Sun, 03 Jul 2005 17:34:25 GMT

HyperSafari is a very interesting little script that employs a lot of exotic custom handlers I've been fine-tuning over the past few days. Whereas it is most useful to me in its current form, I think most people might find parts of its code - some of which haven't been seen anywhere in a script before - inspiring.

Writing it for display on this blog greatly improved its efficiency and general orderliness. In particular I figured out some clever ways of dealing with uncertain window states in applications targeted by a GUI routine.

(* 

HyperSafari 1.0
---------------
Written by Michael Henley (mike.com@mac.com)
July 3, 2005

HyperSafari is basically a digestive aid for the Internet.  It is a 
kitchen-sink script that handles a variety of meddlesome and repetitive 
tasks such as:

- quoting pages with full references
- filing downloaded images with relevant meta-data
- viewing hidden meta-tags
- stimulating the usage of a personal wiki
- harnessing the power of Folksonomy

There are a few ways to use this script, the preferred way (default) 
requires $70 worth of software. I have included, however, optional code 
that will make the script work without some or all of these apps. Keep 
reading for a discussion of the benefits of the various apps, and what to 
do if you don't have them.

The script is designed so that it can constantly "monitor" the activity in 
Safari. Unfortunately Safari can't be taught to notify the script of its 
activities without help from PreFab's $35 UI Actions.
http://prefab.com/uiactions/

If you have UI Actions, great! Simply set this script to fire whenever 
Safari posts the notification "AXValueChanged" and you're done! If you 
don't have UI Actions, you will need to delete the line labeled "Step 1" 
in the code.

The real power of this script shines when used in conjunction with the 
full version of Flying Meat's $25 VoodooPad. VoodooPad will automatically 
highlight keywords in the data it receives, and allow you to populate 
those keywords (or create new keywords) with the data you've collected, 
along with any notes you enter manually.
http://flyingmeat.com/voodoopad/

If you don't want to buy the full version of VoodooPad, consider 
downloading their free version, VoodooPad Lite.  If you select this option 
you will need to delete the handler labeled "Step 2" in the code, and 
activate the handler labeled "Step 3"

If you'd rather not be bothered with VoodooPad at all, I've even included 
a handler for TextEdit.  To use this option, follow steps 2 and 4.

Finally, the activity of the UI action is most useful if you can keep the 
destination app's main window hovering above all other windows on your 
screen using Unsanity's $10 WindowShadeX.
http://www.unsanity.com/haxies/wsx/  

If you don't have WindowShadeX, however, no special modifications are 
necessary. The script will attempt to raise the destination window above 
other background windows without activating it, which is just one step 
below actual hovering.

As an added bonus, I've thrown in a handler that gathers information about 
an individual image that has been loaded in a separate tab or window of 
Safari. It gives you the option to save the image to your hard drive in a 
keyword folder, and then writes links to its local & remote files, its 
dimensions, title, even the website you got it from!

If you don't want to save a particular image, simply click "cancel" when 
the related dialog pops up.  If you don't want the image handler at all, 
follow Step 5, being sure to only cut out the marked code, leaving the 
saveimage() wrappers intact. (this is to prevent an annoying bug that 
occurs in Safari when JavaScript is accidentally run on an image file)

DISCLAIMERS: You assume all risks for your usage and/or modification of 
this code!

*)

ui(false)

property windowLog : ""
global vpDoc, vpPage, targetWindow, windowTest

set vpPage to "launchpad" -- REQUIRED. A blank page (or Text Edit document) to use for auto-updates.
set vpDoc to "mikipiki.vdoc" -- Required for VP. A VoodooPad document to use.
set hfsPath to "hd1:tank:" -- Optional. The folder where Images will be filed by keyword
set posixPath to "/tank/" -- Optional. Same location as hfsPath, used for the save image dialog and URI links

testWindow(hfsPath, posixPath)

on ui(state)
	-- Step 1: If you're not using UI Actions, remove the following line:
	tell application "UI Actions" to set enabled of UI action "Safari-AXValueChanged" to state
end ui

-- Step 2a: Cut out the following block of code if you are going to exercise either step 3 or step 4.
on launchpad(thetext)
	set theDate to (day of (current date) as string) & (characters 1 thru 3 of (month of ¬
		(current date) as string)) & (characters 3 thru 4 of (year of (current date) as string))
	set thetext to theDate & return & thetext
	tell application "System Events" to tell process "VoodooPad"
		set vpWindow to ""
		set theWindows to (name of every window as list)
		repeat with x in theWindows
			if x starts with vpDoc then set vpWindow to x as text
		end repeat
		if vpWindow is "" then display dialog "The document " & vpDoc & " was not found. Make sure that it's open and that the title matches its script variable." buttons {"Cancel"} default button 1
		tell window vpWindow to perform action "AXRaise"
		if vpWindow does not end with vpPage then tell application "VoodooPad" to tell document ¬
			vpDoc to open page with title vpPage
		set value of text area 1 of scroll area 1 of window targetWindow to thetext
	end tell
	set the clipboard to thetext
end launchpad
-- Step 2b: Cut out the preceeding block of code if using an alternate handler.

(* Step 3a: Delete this line to use the VoodooPad Lite handler.

on launchpad(thetext)
	set theDate to (day of (current date) as string) & (characters 1 thru 3 of (month of ¬
		(current date) as string)) & (characters 3 thru 4 of (year of (current date) as string))
	set thetext to theDate & return & thetext
	tell application "System Events" to tell process "VoodooPad Lite"
		set vpWindow to ""
		set theWindows to (name of every window as list)
		repeat with x in theWindows
			if x starts with vpDoc then set vpWindow to x as text
		end repeat
		if vpWindow is "" then display dialog "The document " & vpDoc & ¬
			" was not found. Make sure that it's open and that the title matches its script variable." buttons {"Cancel"} default button 1
		tell window vpWindow to perform action "AXRaise"
		if vpWindow does not end with vpPage then
			tell application "VoodooPad Lite" to activate
			keystroke "o" using {shift down, command down}
			keystroke "o" using {shift down, command down}
			tell sheet 1 of window 1
				set value of combo box 1 to vpPage
				click button "Open"
			end tell
			tell application "Safari" to activate
		end if
		set value of text area 1 of scroll area 1 of window targetWindow to thetext
	end tell
end launchpad

Step 3b: Delete this line to use the VoodooPad Lite handler.  *)

(* Step 4a: Delete this line to use the TextEdit handler.

on launchpad(thetext)
	set theDate to (day of (current date) as string) & (characters 1 thru 3 of (month of ¬
		(current date) as string)) & (characters 3 thru 4 of (year of (current date) as string))
	set thetext to theDate & return & thetext
	tell application "System Events" to tell process "TextEdit"
		set textWindow to ""
		set theWindows to (name of every window as list)
		repeat with x in theWindows
			if x starts with vpPage then set textWindow to x as text
		end repeat
		if textWindow is "" then ¬
			display dialog "To use this script, you must first open a TextEdit document (txt, rtf, etc) named \"" & ¬
				vpPage & "\"" buttons {"Cancel"} default button 1
		tell window textWindow to perform action "AXRaise"
	end tell
	tell application "TextEdit" to set text of document textWindow to thetext
end launchpad

Step 4b: Delete this line to use the TextEdit handler. *)

on saveimage(hfsPath, posixPath)
	
	-- Step 5a cut out this block of code if you don't want automated image filing
	display dialog "Enter a Keyword:" default answer "" buttons {"Cancel", "OK"} default button 2
	set the folderName to the text returned of the result
	tell application "Finder" to if (exists of folder (hfsPath & folderName)) is false then ¬
		make new folder at hfsPath with properties {name:folderName}
	set posixPath to posixPath & folderName
	tell application "Safari" to activate
	tell application "System Events" to tell process "Safari"
		click menu item "Save As…" of menu 1 of menu bar item "File" of menu bar 1
		keystroke "g" using {shift down, command down}
		repeat until (window "Go to Folder" exists)
			delay 0.5
		end repeat
		tell window "Go To Folder"
			set value of text field 1 to posixPath
			click button "Go"
		end tell
		tell sheet 1 of window 1
			set fileName to value of text field 1
			click button 1
		end tell
	end tell
	set vpPath to "file://localhost" & posixPath & "/" & fileName
	tell application "Safari"
		set thetext to (name of window 1 as text) & return & ¬
			(URL of document of window 1 as text) & return & vpPath & return & folderName & return
		tell application "System Events" to keystroke "w" using command down
		set thetext to thetext & "Source: " & (name of window 1 as text) & return & (URL of document of window 1 as text) & return
	end tell
	launchpad(thetext)
	--Step 5b cut out the preceeding block of code if you don't want automated image filing
	
end saveimage

on testWindow(hfsPath, posixPath)
	set targetWindow to vpDoc & ":" & vpPage
	if page_loaded(20) is false then error -128
	if windowLog is "" then set windowLog to windowTest
	if windowTest is not windowLog then
		set windowLog to windowTest
		if windowTest ends with "pixels" then
			saveimage(hfsPath, posixPath)
		else if windowTest begins with "Untitled" then
			error number -128
		else
			safari()
		end if
	else
		ui(true)
	end if
	delay 1
	ui(true)
end testWindow

on safari()
	tell application "Safari"
		repeat with x from 0 to 5 by 1
			set theName to do JavaScript "document.getElementsByTagName(\"meta\").item(" & x & ").name" in document 1
			if theName is "keywords" then exit repeat
		end repeat
		set theKeywords to do JavaScript "document.getElementsByTagName(\"meta\").item(" & x & ").content" in document 1
		set thetext to (do JavaScript "document.title" in document 1) & ¬
			return & (do JavaScript "document.URL" in document 1) & return & theKeywords
	end tell
	launchpad(thetext)
end safari

on page_loaded(timeout_value)
	repeat with i from 1 to the timeout_value
		tell application "Safari"
			set windowTest to (name of window 1 as text)
			if windowTest does not start with "Loading" then
				return true
			else if i is the timeout_value then
				return false
			else
				delay 1
			end if
		end tell
	end repeat
	return false
end page_loaded

Download Files Here

Sat, 02 Jul 2005 08:27:05 GMT

I'm extremely pleased to report my first-ever submission to ScriptBuilders.net! After getting some great feedback on their message boards, I was asked by the the site admin to bundle it up and smack a version number on it. It also happens to be a pretty useful script.